Fórmulas Condicionales

Fórmulas que devuelven valores de campo según condiciones específicas, por ejemplo, devolver “Sí” cuando se cumple la condición o sumar los valores de los campos que coinciden con los criterios.

Fórmulas Condicionales

A continuación se muestra la lista de fórmulas admitidas. Ten en cuenta que las siguientes fórmulas distinguen entre mayúsculas y minúsculas.

Fórmula	Descripción
IF(valor==condición,valor_si_true,valor_si_falso)	Devuelve un valor si la condición se evalúa como VERDADERA u otro valor si la condición se evalúa como FALSO. Para más detalles, haz clic aquí.
IFS(valor=condición1,valor_si_es_verdadero1,valor=condición2,valor_si_es_verdadero2,...,verdadero,valor predeterminado)	Comprueba si se cumplen una o más condiciones y devuelve un valor que corresponda a la primera condición VERDADERA. Para más detalles, haz clic aquí.
LOOKUP(valor,lista_de_búsqueda,[lista_de_resultados])	Busca el valor en un rango de una columna o una fila (lista_de_búsqueda) y devuelve el valor correspondiente de otro rango de una columna o una fila (lista_de_resultados). Para más detalles, haz clic aquí.
AND(lógica1, [lógica2], ...)	Devuelve TRUE si todas sus condiciones son VERDADERAS; devuelve FALSE si una o más condiciones son FALSAS. Para más detalles, haz clic aquí.
OR(lógica1, [lógica2], ...)	Devuelve TRUE si alguna condición es VERDADERA; devuelve FALSE si todas las condiciones son FALSAS. Para más detalles, haz clic aquí.
NOT(lógica)	Devuelve TRUE si la condición de prueba es FALSA y FALSE si la condición es VERDADERA. Para más detalles, haz clic aquí.
UPDATEIF(condición,valor_si_es_verdadero)	Modifica el valor de un campo cuando se cumple al menos una condición. Para más detalles, haz clic aquí
COUNT.IF(rango_criterios;criterios)	Devuelve el número de valores de un rango dentro de un campo de subtabla que cumplen un único criterio especificado. Para más detalles, haz clic aquí.
COUNTIFS(rango_criterios1,criterios1,[rango_criterios2,criterios2]...)	Aplica criterios a campos de varios rangos y cuenta el número de veces que se cumplen todos los criterios. Para obtener más información, haz clic aquí.
SUMIF(rango,criterios,[rango_suma])	Devuelve la suma de los valores de un rango que cumplen un único criterio especificado. Para obtener más información, haz clic aquí.
SUMIFS(rango_suma,rango_criterios1,criterios1,[rango_criterios2, criterios2],...)	Suma todos los argumentos que cumplen los criterios especificados. Para más detalles, haz haz clic aquí.
MAXIFS(rango_máximo, rango_criterios1, criterios1, [rango_criterios2, criterios2], ...)	Devuelve el valor máximo entre las celdas especificadas por un conjunto dado de condiciones o criterios. Para más detalles, haz haz clic aquí.
MINIFS(rango_mín, rango_criterios1, criterios1, [rango_criterios2, criterios2], ...)	Devuelve el valor mínimo entre las celdas especificadas por un conjunto dado de condiciones o criterios. Para más detalles, haz haz clic aquí

Fórmulas Condicionales

Ragic admite el uso de fórmulas condicionales. Ten en cuenta que cambiar el Tipo de Campo también puede afectar los resultados de la calculación en algunos casos.

Nota: Hay dos circunstancias en las que deberás agregar ".RAW" al campo referenciado al asignar fórmulas condicionales:

1. Al usar el operador "=" para hacer referencia a dos campos que cumplen la condición de la fórmula. Sin embargo, al hacer referencia a un solo campo que cumple un valor fijo, no se necesita ".RAW".

2. Al asignar la fórmula a un campo numérico, se utiliza el operador "=" para hacer referencia a un campo de cadena (texto, selección, fecha, etc.) que equivale a un valor de cadena fijo (que devolverá un valor numérico como resultado). Si se hace referencia a un campo numérico que equivale a un valor con el operador "=", no se necesita ".RAW".

Para más detalles sobre ".RAW" por favor vea esta sección.

Los campos tipo fecha son calculados como días.

Las fórmulas condicionales también pueden ser anidadas.

Detalles y Aplicaciones de la Función IF()

Función IF: Evaluación Condicional

La función IF devuelve un valor si una condición especificada es evaluada como verdadera (TRUE), y otro valor si es evaluada como falsa (FALSE).

Fórmula	Sintaxis
IF	IF(valor=condición,valor_si_verdadero,valor_si_falso)

Ejemplos:

Ejemplo 1: IF(A2=10,10,0)

Si el valor en el campo de referencia A2 equivale a 10, entonces el resultado será 10. Si el valor de A2 fuese cualquier otro valor, entonces el resultado sería 0.

Si la fórmula tuviera los siguientes valores: IF(A1=1,'Verdadero','Falso')

Si el valor en el campo referenciado A1 es equivalente a 1, el resultado sería 'Verdadero'. Si el valor fuese cualquier otro, el resultado sería 'Falso'

Uso Práctico: IF(A2>=60,'Si','No')

Si el campo de edad es mayor o igual a 60, el valor en este campo "¿Califica para descuento para personas mayores?" sería "Sí"; de lo contrario, el valor sería "No".

Nota

El uso de la sintaxis antigua de la función IF() sigue disponible.

Valor=='condición'?'valor_si_verdadero':'valor_si_falso'

Ejemplo básico: A1=='abierto'?'O':'C'

Si A1 está abierto, se mostrará O. De lo contrario, dará C.

¿Cuándo agregar .RAW?

1. Referenciar dos campos que equivalen al mismo valor usando la función IF

Si desea referenciar dos campos que equivalen al mismo valor usando el operador "=" como en la fórmulas condicionales, por favor agregue .RAW después de los campos referenciados.

Sintaxis
IF(campo1.RAW=campo2.RAW,valor_si_verdadero,valor_si_falso)

Ejemplos

Ejemplo 1: IF(A1.RAW=A2.RAW,1,0)

Si el valor en el campo referenciado A1 equivale al valor en el campo A2, devolver 1, de lo contrario devolver 0.

Ejemplo 2: IF(A1.RAW=A2.RAW,'Abierto','Cerrado')

Si el valor en el campo referenciado A1 equivale al valor del campo A2, devolver “Abierto”, de lo contrario devolver “Cerrado”.

2. Referenciar un campo de texto cuyo valor equivale a un valor de texto fijado como la condición y devuelve un valor numérico como resultado con la función IF.

Sintaxis
IF(campo1.RAW="texto fijado",valor_numérico_si_verdadero,valor_numérico_si_falso)

Ejemplos

Ejemplo 1: IF(A1.RAW="Si",1,0)

Si el valor en el campo referenciado A1 equivale a “Si”, entonces devolver 1, de lo contrario devolver 0.

Si deseas referenciar un campo numérico que equivale a un valor usando el operador "=", entonces no es necesario usar ".RAW".

Ejemplos: IF(A1=1,'SI','NO')

Si el valor en el campo referenciado A1 equivale a 1, devolver “SI”, de lo contrario devolver “NO”.

3.Determinar si un campo está vacío o no.

Si desea usar una fórmula para saber si un campo está vacío o no, debe agregar .RAW después del campo referenciado.

Por ejemplo, la fórmula IF(A8.RAW='',"VERDADERO","FALSO") se utiliza para comprobar si el campo de la celda A8 está vacío, y el valor de ese campo puede ser 0. Por lo tanto, se debe agregar .RAW.

NOTA: Si tu fórmula no incluye .RAW en el campo referenciado, entonces el valor numérico “0” será considerado como valor vacío.

4. Referenciar el valor numérico de un campo de texto libre y devolverlo como una cadena de texto.

Por ejemplo, si el campo en A1 es un campo de texto libre con el valor numérico "10001", y el campo en A2 es un campo enlazado con una fórmula condicional establecida para hacer referencia y devolver el valor "10001" de A1, la fórmula deberá establecerse de la siguiente manera: IF(A1!='', A1.RAW)

Función IF: Extraer Texto

Si desea extraer texto de los campos referenciados al usar las funciones LEFT(), RIGHT() Y MID(), recuerde agregar +"" después del campo que está referenciando.

Ejemplo:

IF(A1="Si",A5,LEFT(A5+"",2))

Si el valor en el campo referenciado A1 es igual a “Si”, el valor en este campo sería el valor del campo A5. Si A1 tuviese cualquier otro valor, el valor de este este campo sería los primeros 2 dígitos de A5.

Función IF: Referenciar TODAY() o NOW()

Debido a que el sistema no permite referenciar el valor de TODAY() o NOW() directamente en una fórmula IF, deberá crear un campo adicional que haga referencia al campo que contiene el valor de TODAY() o NOW().

Ejemplo:

Si deseas comparar el valor de fecha en el campo A1 a TODAY(), puede crear un campo extra (A2) y configurarlo con la fórmula TODAY(), luego aplicar la siguiente fórmula:

IF(A1>A2,"Válido","Expirado")

Si el valor en campo A1 es mayor al valor de TODAY(), entonces el valor en este campo será "Válido". Si el valor es menor que TODAY(), el valor de este campo será "Expirado".

También podemos usar la fórmula TODAY() o el campo asignado con la fórmula TODAY() como el campo condicional referenciado para calculaciones en fórmulas IF. Puedes crear el campo A2 para la calculación completa como la siguiente: A1-TODAY(). Luego aplicar la siguiente fórmula:

IF(A2>0,"Válido","Expirado")

Nóta: El valor de TODAY() o NOW() no será autocalculado una vez que los registros sean guardados. Si es necesario recalcular el valor de TODAY() o NOW() diariamente, deberás Aplicar Workflow Diariamente.

Función IF: Campo de Fecha

1. Se aplica a un campo que no sea del tipo fecha para comparar los valores de los campos de fecha.

Por ejemplo, A1 y A2 son campos de fecha, aplicar TODAY() a A2. En A4, ingresar la fórmula: IF(A1>A2,"Yes","No")

2. Se aplica en campos numéricos para ejecutar adición o sustracción para campos de fecha.

Por ejemplo, no sería posible ingresar la fórmula IF(A1-1>A2,"Yes","No") en A4. Necesitarás crear los otros dos campos numéricos C1 y C2. En C1, ingresa la fórmula: A1-1. En C2, ingresa A2. En A4, cambia la fórmula a IF(C1>C2,"Yes","No").

Fórmulas Condicionales de Subtabla

Función COUNTIF

La función COUNTIF cuenta el número de filas en una subtabla que cumplen un criterio especificado.. Por ejemplo, contar el número de veces que un artículo aparece en un recibo.

Fórmula	Sintaxis
COUNTIF	COUNTIF(rango_criterio,criterio)

Argumentos:

rango_criterio (Requerido): Este rango debe ser un campo de subtabla a ser evaluado para saber si los valores cumplen el criterio especificado.

criterio (requerido): El criterio que define cuales celdas del rango_criterio serán agregadas. Este puede ser un número, expresión, referencia hacia otro campo, o una cadena de texto que determina cuáles valores serán incluidos. Vea la siguiente tabla:

Aplicación	Ejemplos de Ingreso en Fórmula
Número de Referencia	"8"
Número de Comparación	"> 8"、"< 8"、"!= 8"
Cadena de Texto de Referencia	"manzana"
Inequidad en Cadena de Texto	"!='manzana'"(Usa diferentes comillas fuera y dentro, por ejemplo, comillas dobles fuera, e individuales dentro)
Referencia a Campo de Subtabla	A4 (No necesitas agregar comillas dobles o or "="; solo escribe el nombre del campo)
Comparación con Campo de Subtabla	"> A4"、"< A4"、"!=A4"

COUNTIF sólo puede referirse a una subtabla individual y puede configurarse en campos independientes, sólo admite un criterio, asique debes usar COUNTIFS si deseas usar múltiples criterios.

Ejemplo:

La fórmula COUNTIF(A4,'manzana',A4) ingresada en el campo A9 devuelve el número de celdas bajo la columna A4 que contienen el nombre del producto “manzana”.

Función COUNTIFS

Fórmula	Sintaxis
COUNTIFS	COUNTIFS(rango_criterio1,criterio1,[rango2,criterio2]…)

Argumentos:

rango_criterio1 (requerido): Este rango debe ser un campo de subtabla a ser evaluado para saber si los valores cumplen el criterio especificado.

criterio_1 (requerido): El criterio que define cuales celdas del rango_criterio1 serán agregadas. Este puede ser un número, expresión, referencia hacia otro campo, o una cadena de texto que determina cuáles valores serán incluidos. Vea la siguiente tabla:

Aplicación	Ejemplos de Ingreso en Fórmula
Número de Referencia	"8"
Número de Comparación	"> 8"、"< 8"、"!= 8"
Cadena de Texto de Referencia	"manzana"
Inequidad en Cadena de Texto	"!='manzana'"(Usa diferentes comillas fuera y dentro, por ejemplo, comillas dobles fuera, e individuales dentro)
Referencia a Campo de Subtabla	A4 (No necesitas agregar comillas dobles o or "="; solo escribe el nombre del campo)
Comparación con Campo de Subtabla	"> A4"、"< A4"、"!=A4"

rango_criterio2, criterio2,...(opcional): Filas que pueden ser contadas cuando se cumplen los criterios.

Nota: La función COUNTIFS sólo puede referirse a una subtabla y puede ser configurada en campos independientes.

Función SUMIF

Puedes usar SUMIF para sumar valores guardados en una fila de subtabla especificada y que cumplen un criterio individual. Por ejemplo, sumar el valor monetario de mercancía específica cuando aparece en un recibo.

Fórmula	Sintaxis
SUMIF	SUMIF(rango,criterio,[rango_suma])

Argumentos

rango (requerido): Este rango debe ser un campo de subtabla a ser evaluado para saber si los valores cumplen el criterio especificado.

criterio (requerido): El criterio que define cuales celdas del rango serán agregadas. Este puede ser un número, expresión, referencia hacia otro campo, o una cadena de texto que determina cuáles valores serán incluidos. Vea la siguiente tabla:

Aplicación	Ejemplos de Ingreso en Fórmula
Número de Referencia	"8"
Número de Comparación	"> 8"、"< 8"、"!= 8"
Cadena de Texto de Referencia	"manzana"
Inequidad en Cadena de Texto	"!='manzana'"(Usa diferentes comillas fuera y dentro, por ejemplo, comillas dobles fuera, e individuales dentro)
Referencia a Campo de Subtabla	A4 (No necesitas agregar comillas dobles o or "="; solo escribe el nombre del campo)
Comparación con Campo de Subtabla	"> A4"、"< A4"、"!=A4"

rango_suma (opcional): Los campos a sumar, si deseas agregar valores en campos de subtabla diferentes a los especificados en el argumento rango. Si el argumento rango_suma es omitido, sólo los campos especificados en el argumento rango serán agregados (los mismos campos en los cuales se aplica el criterio).

Nota: SUMIF sólo puede referirse a una subtabla individual y puede configurarse en campos independientes, solo admite un criterio, asique debes usar SUMIFS si deseas usar múltiples criterios.

Ejemplo:

La fórmula SUMIF(A4,'manzana',B4) es ingresada en el campo A9 y devuelve la suma de los valores en la columna B4 cuando el valor del producto bajo el campo A4 es igual a “manzana”.

Función SUMIFS

SUMIFS suma los valores guardaos en una fila de subtabla especificada y que cumplen múltiples criterios. Por ejemplo, sumar el valor monetario de un número de artículos de mercancía en ubicaciones específicas cuando aparecen en un recibo.

Fórmula	Sintaxis
SUMIFS	SUMIFS(rango_suma,rango_criterio1,criterio1,[rango_criterio2,criterio2],…)

Argumentos:

rango_suma (requerido): Este rango debe ser un campo de subtabla a ser evaluado para saber si los valores cumplen el criterio especificado.

rango_criterio1 (requerido): rango_criterio1 y criterio1 deben ser usados en conjunto como un par de búsqueda por el cual un rango es evaluado. Al encontrar los valores que coinciden con el criterio, se agregan los valores correspondientes en el rango_suma.

criterio1 (requerido): El criterio que define cuales celdas del rango_criterio1 serán agregadas. Este puede ser un número, expresión, referencia hacia otro campo, o una cadena de texto que determina cuáles valores serán incluidos. Vea la siguiente tabla:

Aplicación	Ejemplos de Ingreso en Fórmula
Número de Referencia	"8"
Número de Comparación	"> 8"、"< 8"、"!= 8"
Cadena de Texto de Referencia	"manzana"
Inequidad en Cadena de Texto	"!='manzana'"(Usa diferentes comillas fuera y dentro, por ejemplo, comillas dobles fuera, e individuales dentro)
Referencia a Campo de Subtabla	A4 (No necesitas agregar comillas dobles o or "="; solo escribe el nombre del campo)
Comparación con Campo de Subtabla	"> A4"、"< A4"、"!=A4"

rango_criterio2,criterio2,... (opcional): Rangos adicionales y sus criterios asociados.

En caso de que quieras aplicar múltiples criterios a un campo individual, por ejemplo, la suma del campo A1 es igual a A ó B, deberás usar múltiples SUMIF() en lugar de SUMIFS().

Nota: SUMIFS puede usarse en una subtabla y puede configurarse en campos independientes.

Ejemplo:

La fórmula SUMIFS(C11,B11," > A16",B11," < A17") en el campo A18 devuelve la suma de los valores de la columna de subtabla C11 cuando la fecha de la orden (valor de B11) es después de A16 y antes del campo A17.

Función MAXIFS

Devuelve el valor máximo de un rango según uno o más criterios. Normalmente se utiliza para encontrar el precio más alto, el importe o la fecha más reciente.

Fórmula	Sintaxis
MAXIFS	MAXIFS(rango_máximo, rango_criterios1, criterios1, [rango_criterios2, criterios2], ...)

Argumentos:

rango_máximo (requerido): El rango del campo de la subtabla donde se busca el valor máximo.

rango_criterios1 (requerido): El primer rango utilizado para filtrar los datos coincidentes.

criterios1 (requerido): La condición aplicada a criteria_range1; puede ser un número, texto o fórmula.

[rango_criterios2, criterio2] (opcional): Pares adicionales de rango-condición. Solo se incluyen en el cálculo los registros que cumplen todas las condiciones.

Ejemplo 1 (Criterio único): Encuentre el precio unitario más alto de un artículo específico.

En la hoja "Registro de cotización", ingresa MAXIFS("Precio unitario", "Artículo", "Cuaderno") para encontrar el precio unitario más alto de "Cuaderno".

Ejemplo 2 (criterios múltiples): Devolver el precio unitario más alto por categoría y proveedor. Para encontrar el precio unitario más alto donde la categoría es "Papelería" y el proveedor es "Proveedor A", introduzca MAXIFS("Precio Unitario", "Categoría", "Papelería", "Proveedor", "A").

El sistema devuelve el valor más alto entre los registros que cumplen ambos criterios.

Función MINIFS

Devuelve el valor mínimo en un rango basado en uno o más criterios, normalmente utilizado para encontrar el precio más bajo, la cantidad más pequeña o la fecha más temprana.

Fórmula	Sintaxis
MINIFS	MINIFS(rango_mín, rango_criterios1, criterios1, [rango_criterios2, criterios2], ...)

Argumentos:

rango_mín (requerido): El rango del campo de la subtabla donde se busca el valor mínimo.

rango_criterios (obligatorio): El primer rango utilizado para filtrar los datos coincidentes.

criterio1 (requerido): La condición aplicada a criteria_range1; puede ser un número, texto o fórmula.

[rango_criterios2, criterios2] (opcional): Pares adicionales de rango-condición. Solo se incluyen en el cálculo los registros que cumplen todas las condiciones.

Ejemplo 1 (criterio único):Encuentre el precio unitario más bajo para un artículo específico.

En una hoja de "Registro de cotización", ingrese MINIFS("Precio unitario", "Artículo", "Cuaderno") para encontrar el precio unitario más bajo para "Cuaderno".

Ejemplo 2 (Criterios Múltiples): Devuelve el precio unitario más bajo por categoría y proveedor. Para encontrar el precio unitario más bajo donde la categoría es "Papelería" y el proveedor es "Proveedor A", introduce: MINIFS("Precio Unitario", "Categoría", "Papelería", "Proveedor", "A").

El sistema devolverá el valor más bajo entre los registros que cumplan ambas condiciones.

Fórmulas Anidadas con la función IF()

Las fórmulas condicionales pueden ser anidadas cuando múltiples condiciones deben cumplirse.

Ejemplo 1:

IF(A1==1,'Regular',IF(A1==2,'Bueno',IF(A1==3,'Excelente','No Válido')))

La sifuiente fórmula significa que:

si A1 es 1, el resultado es "Regular".

si A1 es 2, el resultado es "Bueno".

si A1 es 3, el resultado es "Excelente".

si A1 fuese cualquier otro valor, el resultado sería "No Válido".

Ejemplo 2:

IF(
	AND(A1.RAW=='Si',A2.RAW=='Jimmy'),
	C3*C7,
	IF(
		AND(A1.RAW=='Si',A2.RAW=='John'),
		C3*C8,
		IF(
			AND(A1.RAW=='Si',A2.RAW=='Jane'),
			C3*C9,
					C3*C10
				)
			)
		)

El fórmula anterior puede interpretarse como:

si A1 tiene el valor "Si", y A2 tiene el valor "Jimmy", el resultado es C3*C7.

si A1 tiene el valor "Si", y A2 tiene el valor "John", el resultado es C3*C8.

si A1 tiene el valor "Si", y A2 tiene el valor "Jane", el resultado es C3*C9.

Si estas condiciones no aplican, entonces el resultado será C3*C10.

Función IFS()

Además de las fórmulas anidadas con la función IF, también puedes usar IFS() para verificar si una o más condiciones se cumplen y devolver un valor que corresponda a la primera condición evaluada como verdadera (TRUE).

Fórmula	Sintaxis
IFS()	IFS(valor==condición1,valor_si_verdadero1,valor=condición2,valor_si_verdadero2,…true,valor predeterminado)

La sintaxis de la función IFS() tiene los siguientes argumentos:

valor==condición1 (requerido): La primera condición que evalúa a VERDADERO O FALSO.

valor_si_verdadero1 (requerido): El resultado a devolver si valor==condición1 es evaluada a VERDADERO.

valor=condición2 (requerido): La segunda condición que evalúa a VERDADERO O FALSO.

valor_si_verdadero2 (requerido): El resultado a devolver si valor=condición2 es evaluada a VERDADERO.

*Debes configurar al menos dos conjuntos de condiciones. Puedes agregar más si es necesario.

true (opcional): Por favor agrega “true” si deseas configurar un valor predeterminado cuando ninguna de las condiciones se cumple.

valor predeterminado (opcional): El resultado a devolver si ninguna de las otras condiciones se cumple.

Ejemplo：

IFS(A1=1,"Regular",A1=2,"Bueno",A1=3,"Excelente",true,"No Válido")

La descripción de la anterior fórmula es:

si A1 es 1, el resultado será "Regular".

si A1 es 2, el resultado será "Bueno".

si A1 es 3, el resultado será "Excelente".

si A1 fuese cualquier otro valor, el resultado será "No Válido".

Otros Detalles y Aplicaciones de Fórmulas

Función Lookup

Devuelve el resultado correspondiente según un rango o condición especificado.

Fórmula	Sintaxis
LOOKUP	LOOKUP(valor_buscado, rango_búsqueda,[lista_resultado])

valor (requerido): El valor del campo que se busca. El sistema busca una coincidencia exacta o la más cercana en la lista de búsqueda.

[rango_de_búsqueda] (requerido): Una matriz como [0, 100, 500] donde BUSCAR busca el valor especificado.

lista_de_resultado (opcional): Define los resultados que se devolverán al encontrar una coincidencia. Debe coincidir con el número de elementos de rando de búsqueda, por ejemplo, ["Pequeño", "Medio", "Grande"]. Si se omite, la función devuelve el valor de lista_de_resultado o, si no se encuentra una coincidencia exacta, el resultado del valor mayor menor o igual al valor especificado. Devuelve un valor en blanco si es menor que todos los elementos.

Ejemplo 1: LOOKUP(A1,[0,45,65],['Pequeño','Mediano','Grande'])

El valor sería “Pequeño” si el valor de A1 fuese un número entre 0 y 44, “Mediano” si el valor fuese un número entre 45-64, y “Largo” para cualquier número igual o mayor a 65.

Ejemplo 2 (referenciando múltiples campos): LOOKUP(A1,[0,45,65],[A3+A4,B5,B6])

El valor sería A3+A4 si el valor de A1 estuviese entre 0 y 44, B5 fuese 45, y B6 si fuese mayor o igual a 65.

Función AND

Devuelve TRUE si todas las condiciones se cumplen, devuelve FALSE si al menos una o más condiciones son falsas.

Fórmula	Sintaxis
AND	AND(lógica1,[lógica2],...)

Argumentos:

lógica1 (requerido): La primera condición que puede ser evaluada como TRUE o FALSE.

lógica2 (opcional): Condiciones adicionales que también afectan si el resultado es TRUE o FALSE.

Función OR

Devuelve TRUE si cualquiera de las condiciones es VERDADERA, devuelve FALSE si todas las condiciones son falsas.

Fórmula	Sintaxis
OR	OR(lógica1,[lógica2],...)

Argumentos:

lógica1 (requerido): La primera condición a ser evaluada como TRUE o FALSE.

lógica2 (opcional): Condiciones adicionales; si cualquier condición devuelve TRUE, todo el resultado devuelverá TRUE.

Función NOT

Devuelve TRUE si la condición es falsa, y FALSE si la condición es TRUE.

Fórmula	Sintaxis
NOT	NOT(lógica)

Ejemplo:

NOT(A2>10)

Si el valor en referencia a A2 es menor o igual a 10, el sistema devuelve "true", de lo contrario devuelve "false".

Función UPDATEIF

Utiliza UPDATEIF para conservar el valor anterior en el campo si la condición es falsa. El valor de un campo donde se utiliza la función UPDATEIF solo debe cambiar si la condición que evalúa la función UPDATEIF es verdadera.

Fórmula	Sintaxis
UPDATEIF	UPDATEIF(condición, valor_si_verdadero)

Argumentos:

condición (requerido): Determina si el campo se actualiza. Si se cumple la condición, el campo se actualiza; de lo contrario, se mantiene igual.

valor_si_es_verdadero (requerido): El valor que se aplica cuando se cumple la condición, que puede ser un número, texto u otra referencia de campo.

Ejemplo

Ejemplo Básico: UPDATEIF(A2==10,10)

Si el valor en el campo A2 es igual a 10, el valor en este campo sería 10. Si A2 fuese cualquier otro valor, entonces el valor de este campo deberá permanecer sin modificaciones desde los últimos cambios guardados.

Ejemplo práctico: UPDATEIF(A2=='Usar dirección de residencia',A1)

Supongamos que el campo A1 es “Dirección de Residencia” y el campo A2 es “Dirección de Entrega”. Sólo se necesita una dirección para enviar los paquetes al cliente, aunque tengamos múltiples direcciones en el perfil. Por lo tanto, usaremos la fórmula:

Si el valor en A2 es 'Usar dirección de residencia', entonces el valor del campo “Dirección de Entrega” sería el mismo valor que A1 (Dirección de Residencia), de lo contrario deberá quedar vacío.